;; Load all the project code
(load "syntax.scm")
(load "meval.scm")
(define *meval-warn-define* #t)
(load "environment.scm")
(load "assert.scm") ; for testing

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(define (m-eval exp env)
  (cond ((self-evaluating? exp) exp)
        ((variable? exp) (lookup-variable-value exp env))    
        ((quoted? exp) (text-of-quotation exp))
        ((assignment? exp) (eval-assignment exp env))
        ((definition? exp) (eval-definition exp env))
        ((if? exp) (eval-if exp env))
        ((lambda? exp)
         (make-procedure (lambda-parameters exp) (lambda-body exp) env))
        ((begin? exp) (eval-sequence (begin-actions exp) env))
        ((cond? exp) (m-eval (cond->if exp) env))
	((let? exp) (m-eval (let->application exp) env))
	((until? exp) (eval-until exp env)) ;; NEW
        ((application? exp)
         (m-apply (m-eval (operator exp) env)
                (list-of-values (operands exp) env)))
        (else (error "Unknown expression type -- EVAL" exp))))

;; until special form (all NEW)
(define (until? exp)            (tagged-list? exp 'until))
(define (until-test exp)        (second exp))
(define (until-expressions exp) (cddr exp))

(define (eval-until exp env)
  (cond ((m-eval (until-test exp) env) 'done)
        (else (eval-sequence (until-expressions exp) env)
              (m-eval exp env))))

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Reset the global environment to make sure it includes
; any tweaks we've made here.
(refresh-global-environment)

; Test: generate a list using an until loop
; Note that this example isn't really very good form, but it was an easy
; way to test out our new special form.  We use the until loop to build
; up an array counting up from 1 to the initial value of x.  We use
; assert-equal to test out our result.
(m-eval '(define x 10) the-global-environment)
(m-eval '(define numbers-viewed '()) the-global-environment)
(m-eval '(until (= x 0)
                (set! numbers-viewed (cons x numbers-viewed))
                (set! x (- x 1)))
        the-global-environment)
(assert-equal (m-eval 'numbers-viewed the-global-environment)
              '(1 2 3 4 5 6 7 8 9 10))